-------------------------------------------------------------------
--           RAPID - RAPID ADA PORTABLE INTERFACE DESIGNER         
--           MCC GUI PACKAGE LIBRARY                               
--           Copyright (C) 1999 Martin C. Carlisle.       
--
-- Adapted from RAPID version 1.2 suggestion by W. Blair Watkinson II
--                                                                 
-- RAPID is free software;  you can  redistribute it  and/or modify
-- it under terms of the  GNU General Public License as published  
-- by the Free Software  Foundation;  either version 2,  or (at your
-- option) any later version.  RAPID is distributed in the hope that 
-- it will be useful, but WITHOUT ANY WARRANTY;  without even the 
-- implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
-- PURPOSE.  See the GNU General Public License for more details.  
-- You should have  received  a copy of the GNU General Public License
-- distributed with RAPID; see file COPYING.  If not, write to the 
-- Free Software Foundation,  59 Temple Place - Suite 330,  Boston, 
-- MA 02111-1307, USA.                                                 
--                                                                     
-- As a special exception, if other files instantiate generics from
-- this unit, or you link this unit with other files to produce an 
-- executable, this unit does not by itself cause the resulting 
-- executable to be covered by the GNU General Public License.  
-- This exception does not however invalidate any other reasons 
-- why the executable file might be covered by the GNU Public 
-- License.  This exception does not apply to executables which
-- are GUI design tools, or that could act as a replacement
-- for RAPID.
------------------------------------------------------------------------------
with MSSyst.Windows;
use MSSyst.Windows;
with MSSyst.Windows.Forms;
use MSSyst.Windows.Forms;
with MSSyst.Windows.Forms.Orientation;
with MSSyst.Windows.Forms.TrackBar;
with MSSyst.Windows.Forms.Control.ControlCollection;
with MSSyst.Object;
with Ada.Unchecked_Conversion;
with MSSyst.EventArgs;
with MSSyst.EventHandler;
with MSSyst;
use MSSyst;

package body Mcc.Gui.Widget.Scale is
   function Convert is new Ada.Unchecked_Conversion(
      MSSyst.Object.Ref, Scale_Pointer);
   function Convert is new Ada.Unchecked_Conversion(
      Scale_Pointer, MSSyst.Object.Ref);

   procedure Dotnet_Changed(
         Sender : MSSyst.Object.Ref;
         E      : EventArgs.Ref) is
      The_Peer : Control.Ref := Control.Ref(Sender);
      Rapid_Pointer : Scale_Pointer;
      Tag : MSSyst.Object.Ref := The_Peer.Get_Tag;
   begin
      Rapid_Pointer := Convert(Tag);
      if Rapid_Pointer.Change_Listener = null then
         return;
      end if;
      Rapid_Pointer.Change_Listener(
         Obj => Rapid_Pointer.all);
   end Dotnet_Changed;

   ------------
   -- Create --
   ------------

   procedure Create
     (Obj                  : in out Scale;
      Parent               : in     Mcc.Gui.Container.Container'Class;
      X                    : in     Integer;
      Y                    : in     Integer;
      Width                : in     Natural;
      Height               : in     Natural;
      Min                  : in     Integer;
      Max                  : in     Integer;
      Mark_Every           : in     Natural;
      Orientation          : in     Scale_Orientation := Horizontal;
      By                   : in     Natural := 1)
   is
      The_Peer : MSSyst.Windows.Forms.TrackBar.Ref;
      type Parent_Access is access constant Mcc.Gui.Container.Container'Class;
      function Convert is new Ada.Unchecked_Conversion(
         Parent_Access,Mcc.Gui.Container.Container_Pointer);
      Parent_Peer : Control.Ref := Control.Ref(
         Mcc.Gui.Container.Get_Peer(Parent));
      Collection : Control.ControlCollection.Ref;
   begin
      The_Peer := MSSyst.Windows.Forms.TrackBar.new_TrackBar;

      -- ok, so it might seem odd to do this, but since we reuse 
      -- variables, it is important to renull these on create   
      Obj.Mouse_Handler := null;   
      Obj.Key_Handler := null;   
      Obj.Change_Listener := null;
      
      Obj.My_Peer := MSSyst.Object.Ref(The_Peer);

      
      Collection := Parent_Peer.Get_Controls;
      Collection.add(Control.Ref(Obj.My_Peer));
      The_Peer.set_Top(y);
      The_Peer.set_Left(x);
      The_Peer.set_Height(Height);
      The_Peer.Set_Width(Width);
      The_Peer.Set_TickFrequency(Mark_Every);
      The_Peer.Set_SmallChange(By);
      The_Peer.Set_Minimum(Min);
      The_Peer.Set_Maximum(Max);
      case Orientation is
         when Horizontal =>
            The_Peer.Set_Orientation(Forms.Orientation.Horizontal);
         when Vertical =>
            The_Peer.Set_Orientation(Forms.Orientation.Vertical);
      end case;
      
      Obj.Parent := Convert(Parent'Unchecked_Access);
   end Create;

   ---------
   -- Get --
   ---------

   function Get (Obj : in Scale) return Integer is
      The_Peer : Forms.TrackBar.Ref := Forms.TrackBar.Ref(Obj.My_Peer);
   begin
      return The_Peer.Get_Value;
   end Get;

   ---------
   -- Set --
   ---------

   procedure Set
     (Obj      : in out Scale;
      Location : in     Integer)
   is
      The_Peer : Forms.TrackBar.Ref := Forms.TrackBar.Ref(Obj.My_Peer);
   begin
      The_Peer.Set_Value(Location);
   end Set;

   procedure Dummy_Scale_Listener(
      Obj   : in out Scale'Class) is
   begin
      null;
   end Dummy_Scale_Listener;
   ------------------------
   -- Set_Scale_Listener --
   ------------------------

   procedure Set_Scale_Listener
     (Obj           : in Scale_Pointer;
      Listener      : in Scale_Listener)
   is
      The_Peer : Forms.TrackBar.Ref := Forms.TrackBar.Ref(Obj.My_Peer);
   begin
      if Obj.Change_Listener = null and then Listener /= null then
         The_Peer.Set_Tag(Convert(Obj));
         The_Peer.Add_ValueChanged(
            EventHandler.New_EventHandler(
               Object => MSSyst.Object.Ref(The_Peer),
               Method => Dotnet_Changed'address));
         Obj.Change_Listener := Listener;
      elsif Obj.Change_Listener /= null and then Listener = null then
         Obj.Change_Listener := Dummy_Scale_Listener'access;
      else
         Obj.Change_Listener := Listener;
      end if;
   end Set_Scale_Listener;

   function Get_Scale_Listener(
      Obj : in Scale'Class) return Scale_Listener is
   begin
      if Obj.Change_Listener = Dummy_Scale_Listener'access then
         return null;
      else
         return Obj.Change_Listener;
      end if;
   end Get_Scale_Listener;

end Mcc.Gui.Widget.Scale;

