-------------------------------------------------------------------
--           RAPID - RAPID ADA PORTABLE INTERFACE DESIGNER         
--           MCC GUI PACKAGE LIBRARY                               
--           Copyright (C) 1999 Martin C. Carlisle.                
--                                                                 
-- RAPID is free software;  you can  redistribute it  and/or modify
-- it under terms of the  GNU General Public License as published  
-- by the Free Software  Foundation;  either version 2,  or (at your
-- option) any later version.  RAPID is distributed in the hope that 
-- it will be useful, but WITHOUT ANY WARRANTY;  without even the 
-- implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
-- PURPOSE.  See the GNU General Public License for more details.  
-- You should have  received  a copy of the GNU General Public License
-- distributed with RAPID; see file COPYING.  If not, write to the 
-- Free Software Foundation,  59 Temple Place - Suite 330,  Boston, 
-- MA 02111-1307, USA.                                                 
--                                                                     
-- As a special exception, if other files instantiate generics from
-- this unit, or you link this unit with other files to produce an 
-- executable, this unit does not by itself cause the resulting 
-- executable to be covered by the GNU General Public License.  
-- This exception does not however invalidate any other reasons 
-- why the executable file might be covered by the GNU Public 
-- License.  This exception does not apply to executables which
-- are GUI design tools, or that could act as a replacement
-- for RAPID.
------------------------------------------------------------------------------
with MSSyst.Windows;
use MSSyst.Windows;
with MSSyst.Windows.Forms;
use MSSyst.Windows.Forms;
with MSSyst.Windows.Forms.ComboBox;
with MSSyst.Windows.Forms.ComboBoxStyle;
with MSSyst.Windows.Forms.ComboBox.ObjectCollection;
with MSSyst.Windows.Forms.Control.ControlCollection;
with MSSyst.Object;
with Ada.Unchecked_Conversion;
with MSSyst.String;
use  MSSyst.String;
with MSSyst.Drawing;
use MSSyst.Drawing;
package body Mcc.Gui.Widget.Dropdown is
   ---------------
   -- Add_Entry --
   ---------------

   procedure Add_Entry
     (Obj      : in out Dropdown;
      Location : in     Natural;
      Text     : in     String)
   is
      The_ComboBox   : ComboBox.Ref;
      The_Collection : ComboBox.ObjectCollection.Ref;
      The_String : MSSyst.String.Ref := +Text;
   begin
      The_ComboBox := ComboBox.Ref(Obj.My_Peer);
      The_Collection := The_ComboBox.get_Items;
      The_Collection.Insert(Location,MSSyst.Object.Ref(The_String));
   end Add_Entry;

   -----------
   -- Clear --
   -----------

   procedure Clear (Obj  : in out Dropdown) is
      The_ComboBox   : ComboBox.Ref;
      The_Collection : ComboBox.ObjectCollection.Ref;
   begin
      The_ComboBox := ComboBox.Ref(Obj.My_Peer);
      The_Collection := The_ComboBox.get_Items;
      The_Collection.Clear;
   end Clear;

   -----------
   -- Count --
   -----------

   function Count (Obj : in Dropdown) return Natural is
      The_ComboBox   : ComboBox.Ref;
      The_Collection : ComboBox.ObjectCollection.Ref;
   begin
      The_ComboBox := ComboBox.Ref(Obj.My_Peer);
      The_Collection := The_ComboBox.get_Items;
      return The_Collection.get_Count;
   end Count;

   ------------
   -- Create --
   ------------

   procedure Create
     (Obj                  : in out Dropdown;
      Parent               : in     Mcc.Gui.Container.Container'Class;
      X                    : in     Integer;
      Y                    : in     Integer;
      Width                : in     Natural;
      Height               : in     Natural;
      Number_Rows          : in     Natural)
   is
      The_Peer : ComboBox.Ref;
      type Parent_Access is access constant Mcc.Gui.Container.Container'Class;
      function Convert is new Ada.Unchecked_Conversion(
         Parent_Access,Mcc.Gui.Container.Container_Pointer);
      Parent_Peer : Control.Ref := Control.Ref(
         Mcc.Gui.Container.Get_Peer(Parent));
      Collection : Control.ControlCollection.Ref;
   begin
      -- ok, so it might seem odd to do this, but since we reuse 
      -- variables, it is important to renull these on create   
      Obj.Mouse_Handler := null;   
      Obj.Key_Handler := null;   

      The_Peer := ComboBox.new_ComboBox;
      Obj.My_Peer := MSSyst.Object.Ref(The_Peer);
      The_Peer.set_MaxDropDownItems(
         Number_Rows);
      The_Peer.Set_DropDownStyle(
         ComboBoxStyle.DropDownList);
      Collection := Parent_Peer.Get_Controls;
      Collection.add(Control.Ref(Obj.My_Peer));
      The_Peer.set_Top(y);
      The_Peer.set_Left(x);
      The_Peer.set_Height(Height);
      The_Peer.set_Width(Width);
      
      Obj.Parent := Convert(Parent'Unchecked_Access);
   end Create;

   ------------------
   -- Delete_Entry --
   ------------------

   procedure Delete_Entry
     (Obj   : in out Dropdown;
      Start : in     Natural;
      Stop  : in     Natural)
   is
      The_ComboBox   : ComboBox.Ref;
      The_Collection : ComboBox.ObjectCollection.Ref;
   begin
      The_ComboBox := ComboBox.Ref(Obj.My_Peer);
      The_Collection := The_ComboBox.get_Items;
      for i in reverse start-1..stop-1 loop
         The_Collection.removeAt(i);
      end loop;
   end Delete_Entry;

   ------------------
   -- Get_Selected --
   ------------------

   function Get_Selected (Obj : in Dropdown) return Natural is
      The_ComboBox   : ComboBox.Ref;
   begin
      The_ComboBox := ComboBox.Ref(Obj.My_Peer);
      return The_ComboBox.get_SelectedIndex + 1;
   end Get_Selected;

   -----------------
   -- Select_Item --
   -----------------

   procedure Select_Item
     (Obj    : in out Dropdown;
      Number : in     Natural)
   is
      The_ComboBox   : ComboBox.Ref;
   begin
      The_ComboBox := ComboBox.Ref(Obj.My_Peer);
      The_ComboBox.set_SelectedIndex(Number - 1);
   end Select_Item;

end Mcc.Gui.Widget.Dropdown;

